# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname='gi-docgen'
_pyname="${_realname/-/_}"
pkgname="${_realname}"
pkgver=2026.1
pkgrel=1
pkgdesc='Documentation generator for GObject-based libraries'
arch=('any')
url='https://gnome.pages.gitlab.gnome.org/gi-docgen/'
msys2_repository_url='https://gitlab.gnome.org/GNOME/gi-docgen'
msys2_changelog_url='https://gitlab.gnome.org/GNOME/gi-docgen/-/blob/main/CHANGES.md'
msys2_references=(
  'anitya: 178582'
  'archlinux: gi-docgen'
  'gentoo: dev-util/gi-docgen'
  'purl: pkg:pypi/gi-docgen'
)
license=('spdx:Apache-2.0 OR GPL-3.0-or-later')
depends=(
  'python'
  'python-jinja'
  'python-markdown'
  'python-markupsafe'
  'python-packaging'
  'python-pygments'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
)
source=("https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
sha256sums=('65ac3c4f2b4255d1c616fb8eae55139b6ca10071545ca2272759ffd2ccf2c7b5')

build() {
  cd "${_pyname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_pyname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
}
