# Maintainer: João Guerra <joca.bt@gmail.com>

pkgname='global'
pkgver=6.7
pkgrel=1
pkgdesc='A source code tagging system'
arch=('i686' 'x86_64')
url='https://www.gnu.org/software/global/'
msys2_references=(
  'anitya: 7987'
  'archlinux: global'
  'cpe: cpe:2.3:a:gnu:global'
  'gentoo: dev-util/global'
)
license=('spdx:GPL-3.0-or-later')
depends=(
  'libltdl'
)
makedepends=(
  'autotools'
  'gcc'
  'gperf'
  'ncurses-devel'
)
optdepends=(
  'ctags'
  'python3-pygments'
)
options=('libtool' '!emptydirs')
source=(
  "https://ftp.gnu.org/gnu/global/${pkgname}-${pkgver}.tar.gz"{,.sig}
  '0001-Fixes-detecting-of-HAVE_SIGSETJMP-in-cygwin.patch'
)
sha256sums=(
  'fdab590c9bda2d68d55e99c51c7e60c2c8595ae4dcebab9bbbb0795f2a5c8bf7'
  'SKIP'
  '46de890ef48c98f66f00b7fbed83ee08fa54d36b38ae007145a584dc3a8064c9'
)
validpgpkeys=(
  '26F631B43D624A927E6F1C33969C3BE389DDA6EB' # Shigio YAMAGUCHI <shigio@gnu.org>
)

prepare() {
  cd "${pkgname}-${pkgver}"

  patch -Np1 -i "${srcdir}/0001-Fixes-detecting-of-HAVE_SIGSETJMP-in-cygwin.patch"

  autoreconf -fiv
}

build() {
  cd "${pkgname}-${pkgver}"

  CFLAGS="${CFLAGS} -std=gnu17" \
    ./configure \
    --prefix=/usr \
    --build="${CHOST}" \
    --host="${CHOST}" \
    --enable-shared \
    --disable-static \
    --with-exuberant-ctags=ctags

  make
}

package() {
  cd "${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
