# Maintainer : Christoph Reiter <reiter.christoph@gmail.com>

pkgname=namcap
pkgver=3.6.0
pkgrel=1
pkgdesc='A Pacman package analyzer'
arch=('any')
url='https://gitlab.archlinux.org/pacman/namcap'
msys2_repository_url='https://gitlab.archlinux.org/pacman/namcap'
msys2_documentation_url='https://wiki.archlinux.org/title/Namcap'
msys2_changelog_url='https://gitlab.archlinux.org/pacman/namcap/-/blob/master/NEWS'
msys2_references=(
  'archlinux: namcap'
)
license=('spdx:GPL-2.0-or-later')
depends=(
  'binutils'
  'python'
  'python-pyalpm'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
)
source=(
  "https://gitlab.archlinux.org/pacman/namcap/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz"
  '001-disable-some-things.patch'
  '002-force-msys-python.patch'
  '003-fix-install-paths.patch'
)
sha256sums=('e191a230d4d616c7327ec6e4d2ef768d3d9a3796723bdeacd8bfdc8d988dc2d0'
            '54a287ab35d1c36020cd38c5e839f7e204e87561c7b2d21a4961068af1e3b901'
            '6f27908efa8fd77067a512bb8d91af6f2b2a8afec6a2d992502c58df652a26ad'
            '28c829c5da34450ba87ac074ad010d4d8246ea0b40f467c435b529ba6f81f694')
noextract=("${pkgname}-${pkgver}.tar.gz")

prepare() {
  tar -xzvf "${pkgname}-${pkgver}.tar.gz" || true

  cd "${pkgname}-${pkgver}"

  patch -Nbp1 -i "${srcdir}/001-disable-some-things.patch"
  patch -Nbp1 -i "${srcdir}/002-force-msys-python.patch"
  patch -Nbp1 -i "${srcdir}/003-fix-install-paths.patch"
}

build() {
  cd "${pkgname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${pkgname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
}
