# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname='Term-Table'
pkgname="perl-${_realname}"
pkgver=0.028
pkgrel=2
pkgdesc='Format a header and rows into a table'
arch=('any')
url='https://metacpan.org/dist/Term-Table'
msys2_repository_url='https://github.com/exodist/Term-Table'
msys2_changelog_url='https://metacpan.org/dist/Term-Table/changes'
msys2_references=(
  'anitya: 12715'
  'gentoo: perl-core/Term-Table'
  'purl: pkg:cpan/EXODIST/Term-Table'
)
license=(
  'spdx:Artistic-1.0-Perl'
  'spdx:GPL-1.0-or-later'
)
groups=('perl-modules')
depends=('perl')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/E/EX/EXODIST/${_realname}-${pkgver}.tar.gz")
sha256sums=('f2ba62a52f32d18aea8a8ca73299bef0e52409332cfe514a9c475316f6d5351c')

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-${pkgver}"

  make test
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"

  make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"

  find "${pkgdir}" -name '.packlist' -delete
  find "${pkgdir}" -name '*.pod' -delete
}
