# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname='URI'
pkgname="perl-${_realname}"
pkgver=5.37
pkgrel=1
pkgdesc='Uniform Resource Identifiers (absolute and relative)'
arch=('any')
url='https://metacpan.org/dist/URI'
msys2_repository_url='https://github.com/libwww-perl/URI'
msys2_changelog_url='https://metacpan.org/dist/URI/changes'
msys2_references=(
  'anitya: 3485'
  'archlinux: perl-uri'
  'gentoo: dev-perl/URI'
  'purl: pkg:cpan/OALDERS/URI'
)
groups=('perl-modules')
license=('spdx:Artistic-1.0-Perl OR GPL-1.0-or-later')
depends=(
  'perl>=5.10.0'
)
checkdepends=(
  'perl-Test-Needs'
  'perl-Test-Warnings'
)
provides=(
  'perl-URI-Escape=3.30'
)
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/O/OA/OALDERS/${_realname}-${pkgver}.tar.gz")
sha256sums=('5a8750ddd8ee743d7cc89bebdd542a9b78a34023164ebe19dea0c248e121c21e')

build() {
  cp -r "${_realname}-${pkgver}" "build-${MSYSTEM}" && cd "build-${MSYSTEM}"

  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "build-${MSYSTEM}"

  # error: MIME::BASE32 is not installed
  # tests: 935 successful, 1 failed
  make test || true
}

package() {
  cd "build-${MSYSTEM}"

  make install DESTDIR="${pkgdir}"
}
