# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname='beaker'
pkgbase="python-${_realname}"
pkgname="python-${_realname}"
pkgver=1.14.1
pkgrel=1
pkgdesc='Caching and sessions WSGI middleware for use with web applications and stand-alone Python scripts and applications'
arch=('any')
url='https://beaker.readthedocs.org'
msys2_repository_url='https://github.com/bbangert/beaker'
msys2_documentation_url='https://beaker.readthedocs.org'
msys2_changelog_url='https://github.com/bbangert/beaker/blob/master/CHANGELOG'
msys2_references=(
  'anitya: 3778'
  'archlinux: python-beaker'
  'cpe: cpe:/a:python:beaker'
  'purl: pkg:pypi/beaker'
)
license=('spdx:BSD-3-Clause')
depends=('python')
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
)
provides=("python3-${_realname}")
conflicts=("python3-${_realname}")
replaces=("python3-${_realname}")
source=("${_realname}-${pkgver}.tar.gz::https://github.com/bbangert/beaker/archive/${pkgver}.tar.gz")
sha256sums=('0033f2dfa89ae5f700b77875c6989172e6f4bf1170a3227f066e63c5b6e6f83f')

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
