# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname='docutils'
pkgname="python-${_realname}"
pkgver=0.23
pkgrel=1
pkgdesc='Set of tools for processing plaintext docs into formats such as HTML, XML, or LaTeX'
arch=('any')
url='https://pypi.org/project/docutils/'
msys2_repository_url='https://sourceforge.net/p/docutils/code'
msys2_documentation_url='https://docutils.sourceforge.io/docs/index.html'
msys2_changelog_url='https://docutils.sourceforge.io/HISTORY.html'
msys2_references=(
  'anitya: 3849'
  'archlinux: python-docutils'
  'gentoo: dev-python/docutils'
  'purl: pkg:pypi/docutils'
)
license=('spdx:LicenseRef-Docutils')
depends=('python')
makedepends=(
  'python-build'
  'python-flit-core'
  'python-installer'
)
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('746f5060322511280a1e50eb76846ed6bf2342984b2ac04dc42caa1a8d78799e')

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
}
