# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname='flit'
pkgname="python-${_realname}-core"
pkgver=4.1.0
pkgrel=1
pkgdesc='Simplified packaging of Python modules (core backend)'
arch=('any')
url='https://flit.pypa.io'
msys2_repository_url='https://github.com/pypa/flit'
msys2_documentation_url='https://flit.pypa.io'
msys2_changelog_url='https://flit.pypa.io/en/stable/history.html'
msys2_references=(
  'anitya: 44841'
  'archlinux: python-flit-core'
  'gentoo: dev-python/flit-core'
  'purl: pkg:pypi/flit-core'
)
license=('spdx:BSD-3-Clause')
depends=(
  'python'
)
source=("${_realname}-${pkgver}.tar.gz::https://github.com/pypa/flit/archive/${pkgver}.tar.gz")
sha256sums=('9f0d26ee4d8345e452fb2fb809966eaca4774baef9933e8174894ded0b7141a1')

build() {
  cd "${_realname}-${pkgver}/flit_core"

  PYTHONPATH='flit_core' python -m flit_core.wheel
}

package() {
  cd "${_realname}-${pkgver}/flit_core"

  local _pythonpath
  _pythonpath="$(python -c "import sysconfig; print(sysconfig.get_path('platlib'))")"

  local _site_packages="${pkgdir}${_pythonpath}"

  mkdir -p "${_site_packages}"

  python bootstrap_install.py -i "${_site_packages}" dist/flit_core-*.whl

  python -m compileall -o 0 -o 1 -q -s "${pkgdir}" -p '/' "${pkgdir}/usr/lib/python"*

  install -Dm644 ../LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
