# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname='mako'
pkgbase="python-${_realname}"
pkgname="python-${_realname}"
pkgver=1.4.1
pkgrel=1
pkgdesc='A super-fast templating language that borrows the best ideas from the existing templating languages'
arch=('any')
url='https://www.makotemplates.org/'
msys2_repository_url='https://github.com/sqlalchemy/mako'
msys2_changelog_url='https://docs.makotemplates.org/en/latest/changelog.html'
msys2_references=(
  'anitya: 3915'
  'archlinux: python-mako'
  'cpe: cpe:/a:sqlalchemy:mako'
  'gentoo: dev-python/mako'
  'purl: pkg:pypi/mako'
)
license=('spdx:MIT')
depends=(
  'python-beaker'
  'python-markupsafe'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
)
checkdepends=(
  'python-pytest'
)
options=('staticlibs')
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('d7904710b662996425a21627710c4777c45053146942cf8a7aebf757c92b8c27')

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "${_realname}-${pkgver}"

  # mako 1.4.1: 3 failed, 537 passed, 30 skipped in 15.79s
  # failed tests: utf-8 characters
  python -m pytest || warning "Tests failed"
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/python-${_realname}/COPYING"
}
