_realname='tomlkit'
pkgname="python-${_realname}"
pkgver=0.15.1
pkgrel=1
pkgdesc='Style preserving TOML library.'
arch=('any')
url='https://tomlkit.readthedocs.io'
msys2_repository_url='https://github.com/python-poetry/tomlkit'
msys2_documentation_url='https://tomlkit.readthedocs.io'
msys2_changelog_url='https://github.com/python-poetry/tomlkit/blob/master/CHANGELOG.md'
msys2_references=(
  'anitya: 19609'
  'archlinux: python-tomlkit'
  'gentoo: dev-python/tomlkit'
  'purl: pkg:pypi/tomlkit'
)
license=('spdx:MIT')
depends=('python')
makedepends=(
  'python-build'
  'python-installer'
  'python-poetry-core'
)
checkdepends=('python-pytest')
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('e25bbf38843005246210a12982776f27f99cb9be67160e14434d0c0d21ee1e97')

build() {
  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "python-build-${MSYSTEM}"

  python -m pytest
}

package() {
  cd "python-build-${MSYSTEM}"

  python -m installer --prefix="${MSYSTEM_PREFIX}" --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
