_realname='vcs-versioning'
_pyname="${_realname/-/_}"
pkgname="python-${_realname}"
pkgver=2.4.1
pkgrel=1
pkgdesc='Core VCS versioning functionality extracted as a standalone library that can be used independently of setuptools.'
arch=('any')
url='https://setuptools-scm.readthedocs.io'
msys2_repository_url='https://github.com/pypa/setuptools-scm'
msys2_documentation_url='https://setuptools-scm.readthedocs.io'
msys2_changelog_url='https://setuptools-scm.readthedocs.io/latest/changelog'
msys2_references=(
  'anitya: 389421'
  'archlinux: python-vcs-versioning'
  'gentoo: dev-python/vcs-versioning'
  'purl: pkg:pypi/vcs-versioning'
)
license=('spdx:MIT')
depends=(
  'python'
  'python-packaging'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-setuptools'
)
checkdepends=(
  'git'
  'python-pytest'
  # useful for check but not available in msys repo
  # 'python-pytest-cov'
  # 'python-pytest-xdist'
)
options=('!strip')
source=("https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
sha256sums=('d4575de3115ec9434393c87c80ffb0eb98a16056bfe2b11ce0f3a97aff67fe0a')

build() {
  cd "${_pyname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "${_pyname}-${pkgver}"

  # 2.1.2: 11 failed, 514 passed, 57 skipped, 84 warnings
  PYTHONPATH="$(pwd)/src" pytest || warning "Tests failed"
}

package() {
  cd "${_pyname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
}
