# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>

pkgbase=rhash
pkgname=("lib${pkgbase}" "lib${pkgbase}-devel" "${pkgbase}")
pkgver=1.4.6
pkgrel=1
pkgdesc='Utility for verifying hash sums of files'
url='https://sourceforge.net/projects/rhash/'
msys2_repository_url='https://github.com/rhash/RHash'
msys2_references=(
  'anitya: 13843'
  'cpe: cpe:2.3:a:rhash_project:rhash'
)
license=('spdx:LicenseRef-RHash AND MIT')
arch=('i686' 'x86_64')
source=(
  "${pkgbase}-${pkgver}.tar.gz::https://github.com/rhash/RHash/archive/v${pkgver}.tar.gz"
  "${pkgbase}-${pkgver}.tar.gz.asc::https://github.com/rhash/RHash/releases/download/v${pkgver}/v${pkgver}.tar.gz.asc"
  '1.4.0_rhash-CYGWIN.patch'
  '002-no-dynamicbase.patch'
  '1.4.4_flags-macros.patch'
)
makedepends=(
  'autotools'
  'gcc'
  'gettext-devel'
  'openssl-devel'
)
sha256sums=('9f6019cfeeae8ace7067ad22da4e4f857bb2cfa6c2deaa2258f55b2227ec937a'
            'SKIP'
            '03334a560bef06e42c438d26923762177eb06759eba8d91ca9853b2157c83bbe'
            'd2914b917bbde58b78c994ae359bda64ff04c7eda124fdfb9b57a25e1b48fee8'
            'fe3b3e794fa175d73f97493aa5bf761a61ecb4006322e94b2f8d0bfdad2437a3')
# https://sourceforge.net/p/rhash/wiki/PublicKey/
validpgpkeys=('2875F6B1C2D27A4F0C8AF60B2A714497E37363AE')

prepare() {
  cd "RHash-${pkgver}"

  patch -Np2 -i "${srcdir}/1.4.0_rhash-CYGWIN.patch"
  patch -Np1 -i "${srcdir}/002-no-dynamicbase.patch"

  patch -Np0 -i "${srcdir}/1.4.4_flags-macros.patch"
}

build() {
  rm -rf "build-${CARCH}"
  cp -r "RHash-${pkgver}" "build-${CARCH}"

  cd "build-${CARCH}"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-lib-static \
    --enable-lib-shared

  make
  make install DESTDIR="${srcdir}/dest" PREFIX=/usr
  make install-gmo LOCALEDIR="${srcdir}/dest/usr/share/locale"
}

check() {
  cd "build-${CARCH}"
  make test
}

package_librhash() {
  pkgdesc='LibRHash shared library'
  groups=('libraries')
  depends=(
    'gcc-libs'
    'libopenssl'
  )

  cd "${srcdir}/dest"

  mkdir -p "${pkgdir}/usr/bin"
  cp -f usr/bin/*.dll "${pkgdir}/usr/bin/"

  cd "${srcdir}/build-${CARCH}"
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgbase}/LICENSE"
}

package_librhash-devel() {
  pkgdesc='Headers and static library for LibRHash'
  groups=('development')
  options=('staticlibs')
  depends=("librhash=${pkgver}")

  cd "${srcdir}/dest"

  mkdir -p "${pkgdir}/usr"
  cp -rf usr/include "${pkgdir}/usr/"
  cp -rf usr/lib "${pkgdir}/usr/"
}

package_rhash() {
  depends=(
    'libiconv'
    'libintl'
    "librhash=${pkgver}"
  )
  backup=('etc/rhashrc')

  cd "${srcdir}/dest"

  mkdir -p "${pkgdir}/usr/bin"
  cp -rf usr/bin/* "${pkgdir}/usr/bin/"
  rm -f "${pkgdir}/usr/bin/"*.dll

  mkdir -p "${pkgdir}/usr/share"
  cp -rf usr/share/* "${pkgdir}/usr/share/"

  mkdir -p "${pkgdir}/etc"
  cp -rf etc/* "${pkgdir}/etc/"
}
