# Maintainer: Alexey Pavlov <alexpux@gmail.com>

pkgbase='unrar'
pkgname=('unrar' 'libunrar' 'libunrar-devel')
pkgver=7.3.1
pkgrel=1
arch=('i686' 'x86_64')
url='https://www.rarlab.com/rar_add.htm'
msys2_references=(
  'anitya: 13306'
  'archlinux: unrar'
  'cpe: cpe:/a:rarlab:unrar'
  'gentoo: app-arch/unrar'
)
license=('spdx:UnRAR')
depends=(
  'gcc-libs'
)
makedepends=(
  'gcc'
  'make'
)
source=(
  "https://www.rarlab.com/rar/unrarsrc-${pkgver}.tar.gz"
  'build-dll.patch'
)
sha256sums=('634900842a3737d9cc15bbcc71d4c74cc713437e0bca296a573424fe5f2660ab'
            '8c618b85478f5b9bb764c523670d0d60a6b14a382919beadf357120d045313b4')

prepare() {
  cd "${pkgbase}"

  patch -Np1 -i "${srcdir}/build-dll.patch"
}

build() {
  cd "${pkgbase}"

  cp -a "${srcdir}/unrar" "${srcdir}/libunrar"

  make -C "${srcdir}/libunrar" lib CXXFLAGS="${CXXFLAGS}"

  make CXXFLAGS="${CXXFLAGS}" STRIP="true"
}

package_unrar() {
  pkgdesc='The RAR uncompression program'
  depends=(
    'gcc-libs'
  )

  cd "${pkgbase}"

  install -Dm755 unrar.exe "${pkgdir}/usr/bin/unrar.exe"

  install -Dm644 license.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_libunrar() {
  pkgdesc='Library file for applications that use libunrar'
  depends=(
    'gcc-libs'
  )

  cd 'libunrar'

  install -Dm755 msys-unrar.dll "${pkgdir}/usr/bin/msys-unrar.dll"

  install -Dm644 license.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_libunrar-devel() {
  pkgdesc='Import library and header file for applications that use libunrar'
  depends=(
    'libunrar'
  )

  cd 'libunrar'

  install -Dm644 libunrar.dll.a "${pkgdir}/usr/lib/libunrar.dll.a"
  install -Dm644 libunrar.a "${pkgdir}/usr/lib/libunrar.a"
  install -Dm644 dll.hpp "${pkgdir}/usr/include/unrar/dll.hpp"
}
