ScriptForge.Array service (SF_Array)

Περιεχόμενα
Δείκτης 🔎︎

# ScriptForge.Υπηρεσία Πίνακας

Παρέχει μια συλλογή μεθόδων για το χειρισμό και τον μετασχηματισμό πινάκων μιας διάστασης (διανύσματα) και πινάκων δύο διαστάσεων (μήτρες). Αυτό περιλαμβάνει λειτουργίες συνόλου, ταξινόμηση, εισαγωγή και εξαγωγή από αρχεία κειμένου.

Πίνακες με περισσότερες από δύο διαστάσεις δεν μπορούν να χρησιμοποιηθούν με τις μεθόδους αυτής της υπηρεσίας, η μόνη εξαίρεση είναι η μέθοδος CountDims που δέχεται Πίνακες με οποιονδήποτε αριθμό διαστάσεων.

Τα στοιχεία πίνακα μπορεί να περιέχουν οποιονδήποτε τύπο τιμής, συμπεριλαμβανομένων (υπο)πινάκων.

## Κλήση υπηρεσίας

Πριν χρησιμοποιήσετε την υπηρεσία Array, η βιβλιοθήκη ScriptForge πρέπει να φορτωθεί χρησιμοποιώντας:

          GlobalScope.BasicLibraries.LoadLibrary("ScriptForge")

Η φόρτωση της βιβλιοθήκης θα δημιουργήσει το αντικείμενο SF_Array που μπορεί να χρησιμοποιηθεί για την κλήση των μεθόδων στην υπηρεσία Array.

Τα παρακάτω αποσπάσματα κώδικα δείχνουν τους διάφορους τρόπους κλήσης μεθόδων στην υπηρεσία Array (η μέθοδος Append χρησιμοποιείται ως παράδειγμα):

          SF_Array.Append(...)

          Dim arr    :    arr = SF_Array
          arr.Append(...)

          Dim arr    :    arr = CreateScriptService("Array")
          arr.Append(...)

The CreateScriptService method is only available after you have loaded the ScriptForge library.

Methods
Append AppendColumn AppendRow Contains ConvertToDictionary CountDims Difference ExportToTextFile ExtractColumn ExtractRow | Flatten ImportFromCSVFile IndexOf Insert InsertSorted Intersection Join2D Prepend PrependColumn PrependRow | RangeInit Reverse Shuffle Slice Sort SortColumns SortRows Transpose TrimArray Union Unique

Το πρώτο όρισμα των περισσότερων μεθόδων είναι το αντικείμενο του πίνακα που πρέπει να ληφθεί υπόψη. Περνιέται πάντα με αναφορά και αφήνεται αμετάβλητο. Μέθοδοι όπως Append, Prepend κ.λπ. επιστρέφουν ένα νέο αντικείμενο πίνακα μετά την εκτέλεσή τους.

## Append

Προσθέτει τα στοιχεία που παρατίθενται ως ορίσματα στο τέλος του πίνακα εισόδου.

### Σύνταξη:

          SF_Array.Append(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Παράμετροι:

Array_1D : the pre-existing array, may be empty.

arg0, ... : a list of items to append to Array_1D.

### Παράδειγμα:

          Sub Example_Append()
          Dim a As Variant
              a = SF_Array.Append(Array(1, 2, 3), 4, 5)
                  ' (1, 2, 3, 4, 5)
          End Sub

## AppendColumn

Προσθέτει μια νέα στήλη στη δεξιά πλευρά ενός δισδιάστατου πίνακα. Ο πίνακας που προκύπτει έχει τα ίδια κάτω όρια με τον αρχικό δισδιάστατο πίνακα.

### Σύνταξη:

          SF_Array.AppendColumn(Array_2D As Variant, New_Column As Variant) As Variant

### Παράμετροι:

Array_2D : the pre-existing array, may be empty. If that array has only one dimension, it is considered as the first column of the resulting two-dimensional array.

New_Column : a 1-dimensional array with as many items as there are rows in Array_2D.

### Παράδειγμα:

          Sub Example_AppendColumn()
          Dim a As Variant, b As variant
              a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((1, 4), (2, 5), (3, 6))
              b = SF_Array.AppendColumn(a, Array(7, 8, 9))
                  ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
              c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
          End Sub

## AppendRow

Προσθέστε στο κάτω μέρος ενός πίνακα δύο διαστάσεων μια νέα σειρά. Ο πίνακας που προκύπτει έχει τα ίδια κάτω όρια με τον αρχικό πίνακα δύο διαστάσεων.

### Σύνταξη:

          SF_Array.AppendRow(Array_2D As Variant, Row As Variant) As Variant

### Παράμετροι:

Array_2D : the pre-existing array, may be empty. If that array has 1 dimension, it is considered as the first row of the resulting 2 dimension array.

Row : a 1D array with as many items as there are columns in Array_2D.

### Παράδειγμα:

          Sub Example_AppendRow()
          Dim a As Variant, b As variant
              a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
                  '  ((1, 2, 3), (4, 5, 6))
              b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
          End Sub

## Contains

Ελέγξτε εάν ένας πίνακας μιας διάστασης περιέχει έναν συγκεκριμένο αριθμό, κείμενο ή ημερομηνία. Η σύγκριση κειμένου μπορεί να είναι με διάκριση πεζών-κεφαλαίων ή όχι.
Οι ταξινομημένοι πίνακες εισόδου πρέπει να γεμίζονται ομοιογενώς, πράγμα που σημαίνει ότι όλα τα στοιχεία πρέπει να είναι βαθμίδες του ίδιου τύπου (τα στοιχεία Empty και Null απαγορεύονται).
Το αποτέλεσμα της μεθόδου είναι απρόβλεπτο όταν ο πίνακας ανακοινώνεται ως ταξινομημένος και στην πραγματικότητα δεν είναι.
Γίνεται μια δυαδική αναζήτηση όταν ταξινομηθεί ο πίνακας, διαφορετικά, απλώς σαρώνεται από πάνω προς τα κάτω και τα στοιχεία Empty και Null αγνοούνται.

### Σύνταξη:

          SF_Array.Contains(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Boolean

### Παράμετροι:

Array_1D : the array to scan.

ToFind : a number, a date or a string to find.

CaseSensitive : Only for string comparisons, default = False.

SortOrder : "ASC", "DESC" or "" (= not sorted, default)

### Παράδειγμα:

          Sub Example_Contains()
          Dim a As Variant
              a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
              SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
          End Sub

## ConvertToDictionary

Αποθηκεύστε το περιεχόμενο ενός πίνακα 2 στηλών σε ένα αντικείμενο ScriptForge.Dictionary.
Το κλειδί θα εξαχθεί από την πρώτη στήλη και το στοιχείο από τη δεύτερη.

### Σύνταξη:

          SF_Array.ConvertToDictionary(Array_2D As Variant) As Variant

### Παράμετροι:

Array_1D : the first column must contain exclusively strings with a length > 0, in any order.

### Παράδειγμα:

          Sub Example_ConvertToDictionary()
          Dim a As Variant, b As Variant
              a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
              b = SF_Array.ConvertToDictionary(a)
              MsgBox b.Item("c") ' 3
          End Sub

## CountDims

Count the number of dimensions of an array. The result can be greater than two.
If the argument is not an array, returns -1
If the array is not initialized, returns 0.

### Σύνταξη:

          SF_Array.CountDims(Array_ND As Variant) As Integer

### Παράμετροι:

Array_ND : the array to examine.

### Παράδειγμα:

          Sub Example_CountDims()
          Dim a(1 To 10, -3 To 12, 5)
              MsgBox SF_Array.CountDims(a) ' 3
          End Sub

## Difference

Δημιουργήστε ένα σύνολο, ως πίνακα μηδενικής βάσης, εφαρμόζοντας τον τελεστή διαφοράς στους δύο πίνακες εισόδου. Τα στοιχεία που προκύπτουν προέρχονται από τον πρώτο πίνακα και όχι από τον δεύτερο.
Ο πίνακας που προκύπτει ταξινομείται με αύξουσα σειρά.
Και οι δύο πίνακες εισόδου πρέπει να συμπληρωθούν ομοιογενώς, τα στοιχεία τους πρέπει να είναι βαθμωτά του ίδιου τύπου. Τα στοιχεία Empty και Null απαγορεύονται.
Η σύγκριση κειμένου μπορεί να κάνει διάκριση πεζών-κεφαλαίων ή όχι.

### Σύνταξη:

          SF_Array.Difference(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Παράμετροι:

Array1_1D : A 1 dimension reference array, whose items are examined for removal.

Array2_1D : A 1 dimension array, whose items are subtracted from the first input array.

CaseSensitive : Only if the arrays are populated with strings, default = False.

### Παράδειγμα:

          Sub Example_Difference()
          Dim a As Variant
              a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("A", "B")
          End Sub

## ExportToTextFile

Γράψτε όλα τα στοιχεία του πίνακα διαδοχικά σε ένα αρχείο κειμένου. Εάν το αρχείο υπάρχει ήδη, θα αντικατασταθεί χωρίς προειδοποίηση.

### Σύνταξη:

          SF_Array.ExportToTextFile(Array_1D As Variant, FileName As String, [Encoding As String]) As Boolean

### Παράμετροι:

Array_1D : The array to export. It must contain only strings.

FileName : the name of the text file containing the data. The name is expressed as given by the current FileNaming property of the SF_FileSystem service. Default = any (both the URL format and the native operating system format are admitted).

Encoding : The character set that should be used. Use one of the names listed in IANA character sets. Note that LibreOffice may not implement all existing character sets. Default is "UTF-8".

### Παράδειγμα:

          Sub Example_ExportToTextFile()
              SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
          End Sub

## ExtractColumn

Εξαγωγή από έναν πίνακα δύο διαστάσεων μιας συγκεκριμένης στήλης ως νέου πίνακα.
Τα κατώτερα LBound και τα ανώτερα όρια UBound είναι ταυτόσημα με αυτά της πρώτης διάστασης του πίνακα εισόδου.

### Σύνταξη:

          SF_Array.ExtractColumn(Array_2D As Variant, ColumnIndex As Long) As Variant

### Παράμετροι:

Array_2D : The array from which to extract.

ColumnIndex : The column number to extract - must be in the interval [LBound, UBound].

### Παράδειγμα:

          Sub Example_ExtractColumn
             'Δημιουργεί μια μήτρα 3x3: |1, 2, 3|
             '                      |4, 5, 6|
             '                      |7, 8, 9|
             Dim mat as Variant, col as Variant
             mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
             mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
             mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
             'Εξάγει την τρίτη στήλη: |3, 6, 9|
             col = SF_Array.ExtractColumn(mat, 2)
          End Sub

## ExtractRow

Εξαγωγή από έναν πίνακα δύο διαστάσεων μιας συγκεκριμένης σειράς ως νέου πίνακα.
Τα κατώτερα LBound και τα ανώτερα όρια UBound είναι ταυτόσημα με αυτά της δεύτερης διάστασης του πίνακα εισόδου.

### Σύνταξη:

          SF_Array.ExtractRow(Array_2D As Variant, RowIndex As Long) As Variant

### Παράμετροι:

Array_2D : The array from which to extract.

RowIndex : The row number to extract - must be in the interval [LBound, UBound].

### Παράδειγμα:

          Sub Example_ExtractRow
             'Δημιουργεί μια μήτρα 3x3: |1, 2, 3|
             '                      |4, 5, 6|
             '                      |7, 8, 9|
             Dim mat as Variant, row as Variant
             mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
             mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
             mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
             'Εξάγει την πρώτη σειρά: |1, 2, 3|
             row = SF_Array.ExtractRow(mat, 0)
          End Sub

## Flatten

Στοιβάξτε όλα τα μεμονωμένα στοιχεία ενός πίνακα και όλα τα στοιχεία στους υποπίνακες του σε έναν νέο πίνακα χωρίς υποπίνακες. Οι κενές υποσυστοιχίες αγνοούνται και οι υποσυστοιχίες με αριθμό διαστάσεων μεγαλύτερο από ένα δεν ισοπεδώνονται.

### Σύνταξη:

          SF_Array.Flatten(Array_1D As Variant) As Variant

### Παράμετροι:

Array_1D : the pre-existing array, may be empty.

### Παράδειγμα:

          Sub Example_Flatten()
          Dim a As Variant
              a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
                  ' (1, 2, 3, 4, 5)
          End Sub

Μπορείτε να χρησιμοποιήσετε τη μέθοδο Flatten μαζί με άλλες μεθόδους, όπως Append ή Prepend για να συνενώσετε ένα σύνολο από πίνακες 1Δ σε έναν μόνο πίνακα 1Δ.

### Παράδειγμα:

Ακολουθεί ένα παράδειγμα του τρόπου με τον οποίο οι μέθοδοι Flatten και Append μπορούν να συνδυαστούν για να συνενώσουν τρεις πίνακες.

          Sub Concatenate_Example
             'Δημιουργεί τρεις πίνακες για αυτό το παράδειγμα
             Dim a as Variant, b as Variant, c as Variant
             a = Array(1, 2, 3)
             b = Array(4, 5)
             c = Array(6, 7, 8, 9)
             'Συνενώνει τους τρεις πίνακες σε έναν ενιαίο πίνακα 1Δ
             Dim arr as Variant
             arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
             '(1, 2, 3, 4, 5, 6, 7, 8, 9)
          End Sub

## ImportFromCSVFile

Εισαγωγή των δεδομένων που περιέχονται σε ένα αρχείο τιμών διαχωρισμένων με κόμματα (CSV). Το κόμμα μπορεί να αντικατασταθεί από οποιονδήποτε χαρακτήρα.

Η ισχύουσα μορφή CSV περιγράφεται στο Κοινή μορφή IETF και Τύπος MIME για αρχεία CSV.

Κάθε γραμμή στο αρχείο περιέχει μια πλήρη εγγραφή (δεν επιτρέπεται ο διαχωρισμός γραμμής).
Ωστόσο, ακολουθίες όπως \n, \t, ... παραμένουν αμετάβλητες. Χρησιμοποιήστε τη μέθοδο SF_String.Unescape() για να τα διαχειριστείτε.

Η μέθοδος επιστρέφει έναν πίνακα δύο διαστάσεων του οποίου οι σειρές αντιστοιχούν σε μια μεμονωμένη εγγραφή που διαβάζεται στο αρχείο και του οποίου οι στήλες αντιστοιχούν σε ένα πεδίο της εγγραφής. Δεν πραγματοποιείται έλεγχος σχετικά με τη συνοχή των τύπων πεδίων στις στήλες. Θα γίνει μια καλύτερη εικασία για τον εντοπισμό αριθμητικών τύπων και τύπων ημερομηνίας.

Εάν μια γραμμή περιέχει λιγότερα ή περισσότερα πεδία από την πρώτη γραμμή του αρχείου, θα δημιουργηθεί μια εξαίρεση. Ωστόσο, οι κενές γραμμές απλώς αγνοούνται. Εάν το μέγεθος του αρχείου υπερβαίνει το όριο του αριθμού των στοιχείων (δείτε μέσα στον κώδικα), εμφανίζεται μια προειδοποίηση και ο πίνακας περικόπτεται.

### Σύνταξη:

          SF_Array.ImportFromCSVFile(FileName As String, [Delimiter As String], [DateFormat As String]) As Variant

### Παράμετροι:

FileName : the name of the text file containing the data. The name is expressed as given by the current FileNaming property of the SF_FileSystem service. Default = any (both the URL format and the native operating system format are admitted).

Delimiter : A single character, usually, a comma, a semicolon or a TAB character. Default = ",".

DateFormat : A special mechanism handles dates when DateFormat is either "YYYY-MM-DD", "DD-MM-YYYY" or "MM-DD-YYYY". The dash (-) may be replaced by a dot (.), a slash (/) or a space. Other date formats will be ignored. Dates defaulting to "" are considered as normal text.

### Παράδειγμα:

Given this CSV file:

          Name,DateOfBirth,Address,City
          Anna,2002/03/31,"Rue de l'église, 21",Toulouse
          Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

          Sub Example_ImportFromCSVFile()
          Dim a As Variant
              a = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
              MsgBox a(0, 3)    ' City
              MsgBox TypeName(a(1, 2))    ' Date
              MsgBox a(2, 2)    ' Rue Albert Einstein, 113A
          End Sub

## IndexOf

Ψάξτε σε έναν πίνακα μιας διάστασης για έναν αριθμό, μια συμβολοσειρά ή μια ημερομηνία. Η σύγκριση κειμένου μπορεί να είναι με διάκριση πεζών-κεφαλαίων ή όχι.
Εάν ο πίνακας είναι ταξινομημένος, πρέπει να συμπληρωθεί ομοιογενώς, πράγμα που σημαίνει ότι όλα τα στοιχεία πρέπει να είναι βαθμίδες του ίδιου τύπου (τα στοιχεία Empty και Null απαγορεύονται).
Το αποτέλεσμα της μεθόδου είναι απρόβλεπτο όταν ο πίνακας ανακοινώνεται ως ταξινομημένος και στην πραγματικότητα δεν είναι.
Εκτελείται δυαδική αναζήτηση σε ταξινομημένους πίνακες. Διαφορετικά, οι πίνακες απλώς σαρώνονται από πάνω προς τα κάτω και τα στοιχεία Empty και Null αγνοούνται.
Η μέθοδος επιστρέφει LBound(input array) - 1 εάν η αναζήτηση δεν ήταν επιτυχής.

### Σύνταξη:

          SF_Array.IndexOf(Array_1D, ToFind As Variant, [CaseSensitive As Boolean], [SortOrder As String]) As Long

### Παράμετροι:

Array_1D : the array to scan.

ToFind : a number, a date or a string to find.

CaseSensitive : Only for string comparisons, default = False.

SortOrder : "ASC", "DESC" or "" (= not sorted, default)

### Παράδειγμα:

          Sub Example_IndexOf()
              MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
              MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
          End Sub

## Insert

Εισαγάγετε πριν από ένα δεδομένο ευρετήριο του πίνακα εισόδου τα στοιχεία που αναφέρονται ως ορίσματα.
Τα ορίσματα εισάγονται τυφλά. Κάθε ένα από αυτά μπορεί να είναι είτε βαθμωτά οποιουδήποτε τύπου είτε υποπίνακας.

### Σύνταξη:

          SF_Array.Insert(Array_1D As Variant, Before As Long, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Παράμετροι:

Array_1D : the pre-existing array, may be empty.

Before : the index before which to insert; must be in the interval [LBound, UBound + 1].

arg0, ... : a list of items to insert inside Array_1D.

### Παράδειγμα:

          Sub Example_Insert()
          Dim a As Variant
              a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
                  ' (1, 2, "a", "b", 3)
          End Sub

## InsertSorted

Insert in a sorted array a new item on its place.
The array must be filled homogeneously, meaning that all items must be scalars of the same type.
Empty and Null items are forbidden.

### Σύνταξη:

          SF_Array.InsertSorted(Array_1D As Variant, Item As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant

### Παράμετροι:

Array_1D : The array to sort.

Item : The scalar value to insert, of the same type as the existing array items.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Παράδειγμα:

          Sub Example_InsertSorted()
          Dim a As Variant
              a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
                  ' ("A", "B", "C", "a", "b")
          End Sub

## Intersection

Δημιουργήστε ένα σύνολο, ως πίνακα μηδενικής βάσης, εφαρμόζοντας τον τελεστή συνόλου τομής στους δύο πίνακες εισόδου. Τα στοιχεία που προκύπτουν περιέχονται και στους δύο πίνακες.
Ο πίνακας που προκύπτει ταξινομείται με αύξουσα σειρά.
Και οι δύο πίνακες εισόδου πρέπει να συμπληρωθούν ομοιογενώς, με άλλα λόγια όλα τα στοιχεία πρέπει να είναι βαθμωτά του ίδιου τύπου. Τα στοιχεία Empty και Null απαγορεύονται.
Η σύγκριση κειμένου μπορεί να κάνει διάκριση πεζών-κεφαλαίων ή όχι.

### Σύνταξη:

          SF_Array.Intersection(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Παράμετροι:

Array1_1D : The first input array.

Array2_1D : The second input array.

CaseSensitive : Applies to arrays populated with text items, default = False.

### Παράδειγμα:

          Sub Example_Intersection()
          Dim a As Variant
              a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("C", "b")
          End Sub

## Join2D

Συνδέστε έναν δισδιάστατο πίνακα με δύο οριοθέτες, έναν για τις στήλες και έναν για τις σειρές.

### Σύνταξη:

          SF_Array.Join2D(Array_2D As Variant, ColumnDelimiter As String, RowDelimiter As String, Quote As Boolean) As String

### Παράμετροι:

Array_2D : Each item must be either text, a number, a date or a boolean.
Dates are transformed into the YYYY-MM-DD hh:mm:ss format.
Invalid items are replaced by a zero-length string.

ColumnDelimiter : Delimits each column (default = Tab/Chr(9)).

RowDelimiter: delimits each row (default = LineFeed/Chr(10))

Quote : if True, protect strings with double quotes. The default is False.

### Παράδειγμα:

          Sub Example_Join2D()
          -                     | 1, 2, "A", [2020-02-29], 5      |
          -    SF_Array.Join_2D(| 6, 7, "this is a string", 9, 10 |, ",", "/")
          -            ' "1,2,A,2020-02-29 00:00:00,5/6,7,this is a string,9,10"
          End Sub

## Prepend

Προσθέστε στην αρχή του πίνακα εισόδου τα στοιχεία που αναφέρονται ως ορίσματα.

### Σύνταξη:

          SF_Array.Prepend(Array_1D As Variant, arg0 As Variant, [arg1 As Variant], ...) As Variant

### Παράμετροι:

Array_1D : the pre-existing array, may be empty.

arg0, ... : a list of items to prepend to Array_1D.

### Παράδειγμα:

          Sub Example_Prepend()
          Dim a As Variant
              a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
                  ' (4, 5, 1, 2, 3)
          End Sub

## PrependColumn

Προσαρτήστε στην αριστερή πλευρά ενός πίνακα δύο διαστάσεων μια νέα στήλη. Ο πίνακας που προκύπτει έχει τα ίδια κατώτερα όρια με τον αρχικό πίνακα δύο διαστάσεων.

### Σύνταξη:

          SF_Array.PrependColumn(Array_2D As Variant, Column As Variant) As Variant

### Παράμετροι:

Array_2D : the pre-existing array, may be empty. If that array has 1 dimension, it is considered as the last column of the resulting 2 dimension array.

Column : a 1 dimension array with as many items as there are rows in Array_2D.

### Παράδειγμα:

          Sub Example_PrependColumn()
          Dim a As Variant, b As variant
              a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((4, 1), (5, 2), (6, 3))
              b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
          End Sub

## PrependRow

Prepend at the beginning of a two dimension array a new row. The resulting array has the same lower boundaries as the initial two dimension array.

### Σύνταξη:

          SF_Array.PrependRow(Array_2D As Variant, Row As Variant) As Variant

### Παράμετροι:

Array_2D : the pre-existing array, may be empty. If that array has 1 dimension, it is considered as the last row of the resulting 2 dimension array.

Row : a 1 dimension array containing as many items as there are rows in Array_2D.

### Παράδειγμα:

          Sub Example_PrependRow()
          Dim a As Variant, b As variant
              a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
                  ' ((4, 5, 6), (1, 2, 3))
              b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
                  ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
          End Sub

## RangeInit

Αρχικοποίηση ενός νέου πίνακα μηδενικής βάσης με αριθμητικές τιμές.

### Σύνταξη:

          SF_Array.RangeInit(From As [number], UpTo As [number] [, ByStep As [number]]) As Variant

### Παράμετροι:

From : value of the first item.

UpTo : The last item should not exceed UpTo.

ByStep : The difference between two successive items (default = 1).

### Παράδειγμα:

          Sub Example_RangeInit()
          Dim a As Variant
              a = SF_Array.RangeInit(10, 1, -1)
                  ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
          End Sub

## Reverse

Επιστροφή του αντίστροφου πίνακα εισόδου μιας διάστασης.

### Σύνταξη:

          SF_Array.Reverse(Array_1D As Variant) As Variant

### Παράμετροι:

Array_1D : The array to reverse.

### Παράδειγμα:

          Sub Example_Reverse()
          Dim a As Variant
              a = SF_Array.Reverse(Array("a", 2, 3, 4))
                  ' (4, 3, 2, "a")
          End Sub

## Shuffle

Return a random permutation of a one dimension array.

### Σύνταξη:

          SF_Array.Shuffle(Array_1D As Variant) As Variant

### Παράμετροι:

Array_1D : The array to shuffle.

### Παράδειγμα:

          Sub Example_Shuffle()
          Dim a As Variant
              a = SF_Array.Shuffle(Array(1, 2, 3, 4))
                  ' Unpredictable
          End Sub

## Slice

Return a subset of a one dimension array.

### Σύνταξη:

          SF_Array.Slice(Array_1D As Variant, From As Long, [UpTo As Long]) As Variant

### Παράμετροι:

Array_1D : The array to slice.

From : The lower index in Array_1D of the subarray to extract (From included)

UpTo : The upper index in Array_1D of the subarray to extract (UpTo included). Default = upper bound of Array_1D. If UpTo < From then the returned array is empty.

### Παράδειγμα:

          Sub Example_Slice()
          Dim a As Variant
              a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
          End Sub

## Sort

Ταξινόμηση ενός πίνακα μιας διάστασης σε αύξουσα ή φθίνουσα σειρά. Οι συγκρίσεις κειμένων μπορεί να είναι με διάκριση πεζών-κεφαλαίων ή όχι.
Ο πίνακας πρέπει να γεμίσει ομοιογενώς, πράγμα που σημαίνει ότι τα στοιχεία πρέπει να είναι βαθμωτά του ίδιου τύπου. Επιτρέπονται τα στοιχεία
Empty και Null. Συμβατικά Empty < Null < οποιαδήποτε άλλη βαθμωτή τιμή.

### Σύνταξη:

          SF_Array.Sort(Array_1D As Variant, SortOrder As String, CaseSensitive As Boolean) As Variant

### Παράμετροι:

Array_1D : The array to sort.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Παράδειγμα:

          Sub Example_Sort()
          Dim a As Variant
              a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
                  ' ("A", "B", "C", "a", "b")
          End Sub

## SortColumns

Επιστροφή μιας μετάθεσης των στηλών ενός πίνακα δύο διαστάσεων, ταξινομημένων με βάση τις τιμές μιας δεδομένης σειράς.
Η σειρά πρέπει να γεμίσει ομοιογενώς, πράγμα που σημαίνει ότι όλα τα στοιχεία πρέπει να είναι βαθμωτά του ίδιου τύπου. Επιτρέπονται τα στοιχεία
Empty και Null. Συμβατικά Empty < Null < οποιαδήποτε άλλη βαθμωτή τιμή.

### Σύνταξη:

          SF_Array.SortColumns(Array_1D As Variant, RowIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant

### Παράμετροι:

Array_1D : The array to sort.

RowIndex : The index of the row to sort the columns on.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Παράδειγμα:

          Sub Example_SortColumns()
          -                         | 5, 7, 3 |            ' | 7, 5, 3 |
          -    SF_Array.SortColumns(| 1, 9, 5 |, 2, "ASC") ' | 9, 1, 5 |
          -                         | 6, 1, 8 |            ' | 1, 6, 8 |
          End Sub

## SortRows

Επιστροφή μιας μετάθεσης των γραμμών ενός πίνακα δύο διαστάσεων, ταξινομημένων με βάση τις τιμές μιας δεδομένης στήλης.
Η στήλη πρέπει να γεμίσει ομοιογενώς, επομένως όλα τα στοιχεία πρέπει να είναι βαθμίδες του ίδιου τύπου. Επιτρέπονται τα στοιχεία
Empty και Null. Συμβατικά Empty < Null < οποιαδήποτε άλλη βαθμωτή τιμή.

### Σύνταξη:

          SF_Array.SortRows(Array_1D As Variant, ColumnIndex As Long, SortOrder As String, CaseSensitive As Boolean) As Variant

### Παράμετροι:

Array_1D : The array to sort.

RowIndex : The index of the column to sort the rows on.

SortOrder : "ASC" (default) or "DESC".

CaseSensitive : Only for string comparisons, default = False.

### Παράδειγμα:

          Sub Example_SortRows()
          -                      | 5, 7, 3 |            ' | 1, 9, 5 |
          -    SF_Array.SortRows(| 1, 9, 5 |, 2, "ASC") ' | 5, 7, 3 |
          -                      | 6, 1, 8 |            ' | 6, 1, 8 |
          End Sub

## Transpose

Swap rows and columns in a two dimension array.

### Σύνταξη:

          SF_Array.Transpose(Array_2D As Variant) As Variant

### Παράμετροι:

Array_2D : The array to transpose.

### Παράδειγμα:

          Sub Example_Transpose()
          -                       | 1, 2 |  ' | 1, 3, 5 |
          -    SF_Array.Transpose(| 3, 4 |) ' | 2, 4, 6 |
          -                       | 5, 6 |
          End Sub

## TrimArray

Κατάργηση από έναν πίνακα μιας διάστασης όλων των καταχωρήσεων Null, Empty και μηδενικού μήκους.
Τα στοιχεία συμβολοσειράς περικόπτονται με τη συνάρτηση του LibreOffice Basic Trim().

### Σύνταξη:

          SF_Array.TrimArray(Array_1D As Variant) As Variant

### Παράμετροι:

Array_1D : The array to scan.

### Παράδειγμα:

          Sub Example_TrimArray()
          Dim a As Variant
              a = SF_Array.TrimArray(Array("A","B",Null," D "))
                  ' ("A","B","D")
          End Sub

## Union

Build a set, as a zero-based array, by applying the union operator on the two input arrays. Resulting items originate from both arrays.
The resulting array is sorted in ascending order.
Both input arrays must be filled homogeneously, their items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.

### Σύνταξη:

          SF_Array.Union(Array1_1D As Variant, Array2_1D As Variant[, CaseSensitive As Boolean]) As Variant

### Παράμετροι:

Array1_1D : The first input array.

Array2_1D : The second input array.

CaseSensitive : Only if the arrays are populated with strings, default = False.

### Παράδειγμα:

          Sub Example_Union()
          Dim a As Variant
              a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
                  ' ("A", "B", "C", "Z", "b")
          End Sub

## Unique

Δημιουργία ενός συνόλου μοναδικών τιμών που προέρχονται από τον πίνακα εισόδου.
Ο πίνακας εισόδου πρέπει να συμπληρωθεί ομοιογενώς, τα στοιχεία του πρέπει να είναι βαθμωτές του ίδιου τύπου. Τα στοιχεία Empty και Null απαγορεύονται.
Η σύγκριση κειμένου μπορεί να κάνει διάκριση πεζών-κεφαλαίων ή όχι.

### Σύνταξη:

          SF_Array.Unique(Array_1D As Variant, CaseSensitive As Boolean]) As Variant

### Παράμετροι:

Array_1D : The input array.

CaseSensitive : Only if the array is populated with texts, default = False.

### Παράδειγμα:

          Sub Example_Unique()
          Dim a As Variant
              a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
                  '  ("A", "B", "C", "b")
          End Sub

Όλες οι ScriptForge ρουτίνες Basic ή αναγνωριστικά που έχουν το πρόθεμα χαρακτήρα υπογράμμισης "_" δεσμεύονται για εσωτερική χρήση. Δεν προορίζεται να χρησιμοποιηθούν σε μακροεντολές Basic.

Σχετικά θέματα

Συναρτήσεις πίνακα

Κλήση συναρτήσεων Calc

Υπηρεσία ScriptForge.Dictionary