Περιεχόμενα
Δείκτης 🔎︎

# Οικονομικές συναρτήσεις - Μέρος πρώτο

Η κατηγορία αυτή περιέχει τις οικονομικές μαθηματικές συναρτήσεις του LibreOffice Calc.

## ISPMT

Αυτή η παράμετρος σας επιτρέπει να υπολογίσετε τα επίπεδα του επιτοκίου για αμετάβλητες χρεολυτικές δόσεις.

#### Σύνταξη

ISPMT(επιτόκιο; Περίοδος; ΣύνολοΠεριόδων; Επένδυση)

Επιτόκιο είναι το περιοδικό επιτόκιο.

Περίοδος είναι ο αριθμός των δόσεων για τον υπολογισμό του τόκου.

ΣύνολοΠεριόδωνείναι ο συνολικός αριθμός περιόδων των δόσεων.

Επένδυση είναι το ποσό της επένδυσης.

#### Παράδειγμα

Για ένα ποσό πίστωσης 120.000 νομισματικών μονάδων, με διάρκεια δύο ετών και μηνιαίες δόσεις, με επιτόκιο 12%, ζητείται ο τόκος μετά από 1,5 χρόνο.

=ISPMT(1%;18;24;120000) = -300 νομισματικές μονάδες. Ο μηνιαίος τόκος μετά από 1,5 χρόνο ανέρχεται σε 300 νομισματικές μονάδες.

## DDB

Επιστρέφει την απόσβεση ενός περιουσιακού στοιχείου για μια καθορισμένη περίοδο, χρησιμοποιώντας την αριθμητική-φθίνουσα μέθοδο.

Χρησιμοποιήστε αυτήν τη μορφή απόσβεσης, εάν θέλετε μια υψηλότερη αρχική τιμή απόσβεσης (σε αντίθεση με την γραμμική απόσβεση). Η τιμή απόσβεσης μειώνεται με το πέρας κάθε περιόδου και συνήθως χρησιμοποιείται για περιουσιακά στοιχεία των οποίων η απώλεια αξίας είναι υψηλότερη πολύ σύντομα μετά την αγορά τους (π.χ. οχήματα, υπολογιστές). Έχετε υπόψη ότι η λογιστική αξία δεν θα φτάσει ποτέ το μηδέν, με αυτόν τον τρόπο υπολογισμού.

#### Σύνταξη

DDB(Κόστος; ΥπολειμματικήΑξία; Ζωή; Περίοδος; Συντελεστής)

Κόστος ορίζει το αρχικό κόστος ενός περιουσιακού στοιχείου.

ΥπολειμματικήΑξία ορίζει την τιμή ενός περουσιακού στοιχείου στο τέλος της ζωής του.

Ζωή είναι ο αριθμός των περιόδων (π.χ., έτη ή μήνες) που καθορίζουν τη διάρκεια χρήσης του περιουσιακού στοιχείου.

Η Περίοδος καθορίζει την περίοδο για την οποία θα υπολογιστεί η τιμή.

Συντελεστής (προαιρετικός) είναι ο συντελεστής κατά τον οποίο μειώνεται η απόσβεση. Εάν δεν εισαχθεί τιμή, η προεπιλογή είναι συντελεστής 2.

#### Παράδειγμα

Ένα σύστημα υπολογιστή με αρχικό κόστος 75.000 νομισματικές μονάδες, θα αποσβεστεί μηνιαίως σε διάρκεια 5 ετών. Η αξία στο τέλος της απόσβεσης θα είναι 1 νομισματική μονάδα. Ο συντελεστής είναι 2.

=DDB(75000;1;60;12;2) = 1.721,81 νομισματικές μονάδες. Συνεπώς, η διπλά φθίνουσα απόσβεση στη διάρκεια του πρώτου μήνα μετά την αγορά, είναι 1.721,81 νομισματικές μονάδες.

## DB

Επιστρέφει την απόσβεση ενός περιουσιακού στοιχείου για μια ορισμένη περίοδο χρησιμοποιώντας τη μέθοδο της σταθερής απομείωσης υπολοίπου.

Αυτή η μορφή απόσβεσης χρησιμοποιείται εφόσον θέλετε υψηλότερη τιμή απόσβεσης στην αρχή της απόσβεσης (σε αντίθεση με τη γραμμική απόσβεση). Η τιμή απόσβεσης μειώνεται σε κάθε περίοδο απόσβεσης κατά το ποσό απόσβεσης που έχει ήδη αφαιρεθεί από το αρχικό κόστος.

#### Σύνταξη

DB(Κόστος; ΥπολειμματικήΑξία; Ζωή; Περίοδος; Μήνας)

Κόστος είναι το αρχικό κόστος ενός περιουσιακού στοιχείου.

ΥπολειμματικήΑξία είναι η αξία ενός περιουσιακού στοιχείου στο τέλος της απόσβεσης.

Ζωή καθορίζει την περίοδο απόσβεσης περουσιακού στοιχείου.

Περίοδος είναι το μήκος κάθε περιόδου. Το μήκος πρέπει να έχει τις ίδιες μονάδες ημερομηνίας όπως και η περίοδος απόσβεσης.

Μήνας (προαιρετικό) υποδηλώνει τον αριθμό των μηνών για το πρώτο έτος απόσβεσης. Εάν δεν υπάρχει καταχώριση, χρησιμοποιείται το 12 ως προεπιλογή.

#### Παράδειγμα

Η απόσβεση ενός συστήματος υπολογιστή με αρχικό κόστος 25.000 νομισματικές μονάδες θα διαρκέσει τρία χρόνια. Η υπολειμματική αξία θα είναι 1.000 νομισματικές μονάδες. Μία περίοδος διαρκεί 30 ημέρες.

=DB(25000;1000;36;1;6) = 1.075,00 νομισματικές μονάδες

Η σταθερά φθίνουσα απόσβεση του συστήματος υπολογιστή είναι 1.075,00 νομισματικές μονάδες.

## PV

Επιστρέφει την παρούσα αξία μιας επένδυσης, η οποία προκύπτει από μια σειρά τακτικών καταβολών.

Χρησιμοποιήστε αυτήν τη συνάρτηση για να υπολογίσετε το ποσό των χρημάτων που χρειάζεστε για να επενδύσετε με σταθερό επιτόκιο σήμερα, για να εισπράξετε ένα συγκεκριμένο ποσό, ένα ετήσιο ποσό, σε συγκεκριμένο αριθμό περιόδων. Μπορείτε επίσης να καθορίσετε πόσα χρήματα θα μείνουν μετά το πέρας της περιόδου. Καθορίστε επίσης εάν το ποσό θα πληρώνεται στην αρχή ή στο τέλος της περιόδου.

Εισάγετε αυτές τις τιμές ως αριθμούς, εκφράσεις ή παραπομπές. Εάν, για παράδειγμα, ο τόκος καταβάλλεται ετησίως σε ποσοστό 8%, αλλά εσείς θέλετε να χρησιμοποιήσετε το μήνα ως περίοδο αναφοράς, εισάγετε 8%/12 για τον Τόκος και το LibreOffice Calc θα υπολογίσει αυτόματα το σωστό συντελεστή.

#### Σύνταξη

PV(Επιτόκιο; ΑριθμόςΠεριόδων; ΔόσηΑποπληρωμής; ΜελλοντικήΑξία; Τύπος)

Επιτόκιο καθορίζει το επιτόκιο ανά περίοδο.

ΑριθμόςΠεριόδων είναι ο συνολικός αριθμός περιόδων (περίοδος πληρωμής).

ΔόσηΑποπληρωμής είναι η κανονική πληρωμή που γίνεται ανά περίοδο.

ΜελλοντικήΑξία (προαιρετικό) καθορίζει την υπολειπόμενη μελλοντική αξία μετά την πληρωμή της τελικής δόσης.

Τύπος (προαιρετικό) υποδηλώνει την οφειλόμενη ημερομηνία πληρωμών. Τύπος = 1 σημαίνει οφειλή στην αρχή της περιόδου και Τύπος = 0 (προεπιλογή) σημαίνει οφειλή στο τέλος της περιόδου.

Στις συναρτήσεις του LibreOffice Calc, οι παράμετροι που σημειώνονται ως "προαιρετικές" μπορούν να παραληφθούν μόνο όταν δεν ακολουθεί καμιά παράμετρος. Παραδείγματος χάρη, σε μια συνάρτηση με τέσσερις παραμέτρους, όπου οι δύο τελευταίες παράμετροι είναι σημειωμένες ως "προαιρετικές", μπορείτε να αφήσετε έξω την παράμετρο 4 ή τις παραμέτρους 3 και 4, αλλά δεν μπορείτε να παραλείψετε μόνο την παράμετρο 3.

#### Παράδειγμα

Ποια είναι η παρούσα αξία μιας επένδυσης, εάν καταβάλλονται 500 νομισματικές μονάδες μηνιαίως και το ετήσιο επιτόκιο είναι 8%; Η περίοδος καταβολής είναι 48 μήνες και στο τέλος της περιόδου καταβολών θα υπάρχουν 20.000 νομισματικές μονάδες.

=PV(8%/12;48;500;20000) = -35.019,37 νομισματικές μονάδες. Στις δεδομένες συνθήκες, πρέπει να καταθέσετε 35 019,37 νομισματικές μονάδες σήμερα, εάν θέλετε να πάρετε 500 νομισματικές μονάδες ανά μήνα για 48 μήνες και να έχετε υπόλοιπο 20 000 νομισματικές μονάδες στο τέλος. Μια διασταύρωση δείχνει ότι 48 x 500 λογιστικές μονάδες + 20 000 λογιστικές μονάδες = 44 000 λογιστικές μονάδες. Η διαφορά μεταξύ αυτού του ποσού και των 35 000 κατατεθειμένων λογιστικών μονάδων αντιπροσωπεύει το πληρωμένο επιτόκιο.

Αν εισάγετε παραπομπές κελιών αντί για τις τιμές αυτές στον τύπο, μπορείτε να υπολογίσετε οποιοδήποτε σενάριο "Αν-τότε". Παρακαλώ σημειώστε: οι παραπομπές στις σταθερές πρέπει να ορισθούν ως απόλυτες παραπομπές. Παραδείγματα αυτού του τύπου εφαρμογών μπορείτε να βρείτε στις συναρτήσεις απόσβεσης.

## EFFECT

Επιστρέφει το καθαρό ετήσιο επιτόκιο για ένα ονομαστικό επιτόκιο.

Το ονομαστικό επιτόκιο αναφέρεται στον τόκο που είναι πληρωτέος στο τέλος της περιόδου υπολογισμού. Το πραγματικό επιτόκιο αυξάνεται με τον αριθμό των πληρωμών που πραγματοποιούνται. Δηλαδή, ο τόκος συχνά καταβάλλεται εκ των προτέρων (για παράδειγμα, με μηνιαίες, τριμηνιαίες κτλ. δόσεις) πριν από το τέλος της περιόδου υπολογισμού.

#### Σύνταξη

EFFECTIVE(Nom; P)

Ονομαστικός είναι ο ονομαστικός τόκος.

Περίοδοι είναι ο αριθμός των περιόδων πληρωμών τόκων ανά έτος.

#### Παράδειγμα

Εάν το ετήσιο ονομαστικό επιτόκιο είναι 9,75% και έχουν καθοριστεί τέσσερις περίοδοι υπολογισμού, ποιο είναι το πραγματικό επιτόκιο (ωφέλιμο επιτόκιο);

=EFFECT(9,75%;4) = 10,11%. Ο ετήσιος πραγματικός τόκος είναι κατά συνέπεια 10,11%.

## SYD

Επιστρέφει τον αριθμητικό-φθίνοντα ρυθμό απόσβεσης.

Χρησιμοποιήστε αυτήν τη συνάρτηση για να υπολογίσετε το ποσό απόσβεσης για μια περίοδο του συνόλου της περιόδου απόσβεσης ενός αντικειμένου. Η αριθμητική φθίνουσα απόσβεση μειώνει το ποσό απόσβεσης από περίοδο σε περίοδο κατά ένα σταθερό ποσό.

#### Σύνταξη

SYD(Κόστος;ΥπολειμματικήΑξία;Ζωή;Περίοδος)

Κόστος είναι το αρχικό κόστος ενός περιουσιακού στοιχείου.

ΥπολειμματικήΑξία είναι η τιμή περουσιακού στοιχείου μετά την απόσβεση.

Ζωή είναι η περίοδος που καθορίζει το χρόνο απόσβεσης ενός περιουσιακού στοιχείου.

Η Περίοδος καθορίζει την περίοδο για την οποία θα υπολογιστεί η απόσβεση.

#### Παράδειγμα

Πρόκειται να γίνει απόσβεση ενός βίντεο με αρχική τιμή 50.000 νομισματικές μονάδες, σε ετήσια βάση, για τα επόμενα 5 χρόνια. Η υπολειμματική (αναπόσβεστη) αξία θα είναι 10.000 νομισματικές μονάδες. Θέλετε να υπολογίσετε την απόσβεση για τον πρώτο χρόνο.

=SYD(50000;10000;5;1)=13.333,33 νομισματικές μονάδες. Το ποσό απόσβεσης για το πρώτο έτος είναι 13.333,33 νομισματικές μονάδες.

Για να έχετε μια επισκόπηση των ρυθμών απόσβεσης ανά περίοδο, είναι καλύτερο να καθορίσετε έναν πίνακα απόσβεσης. Εισάγοντας τους διάφορους τύπους απόσβεσης που είναι διαθέσιμοι στο LibreOffice Calc, τον έναν δίπλα στον άλλον, μπορείτε να δείτε ποια μορφή απόσβεσης είναι η πιο κατάλληλη. Εισαγάγετε τον πίνακα ως εξής:

| Α | Β | C | D | E
1 | Αρχικό κόστος | Υπολειμματική τιμή | Ωφέλιμη ζωή | Χρονική περίοδος | Απόσβεση SYD
2 | 50 000 νομισματικές μονάδες | 10 000 νομισματικές μονάδες | 5 | 1 | 13.333,33 νομισματικές μονάδες
3 |  |  |  | 2 | 10.666,67 νομισματικές μονάδες
4 |  |  |  | 3 | 8.000,00 νομισματικές μονάδες
5 |  |  |  | 4 | 5.333,33 νομισματικές μονάδες
6 |  |  |  | 5 | 2.666,67 νομισματικές μονάδες
7 |  |  |  | 6 | 0,00 νομισματικές μονάδες
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | 0 |  |  | Άθροισμα | 40.000,00 νομισματικές μονάδες

Ο τύπος στο κελί E2 έχει ως εξής:

=SYD($A$2;$B$2;$C$2;D2)

Αυτός ο τύπος επαναλαμβάνεται στη στήλη E έως το κελί E11 (επιλέξτε το κελί E2 και στη συνέχεια σύρετε με το ποντίκι έως την κάτω δεξιά γωνία).

Το κελί E13 περιέχει τον τύπο που χρησιμοποιείται για τον έλεγχο του συνόλου των ποσών απόσβεσης. Χρησιμοποιεί τη συνάρτηση SUMIF, καθώς οι αρνητικές τιμές στα κελιά E8:E11 δεν πρέπει να ληφθούν υπόψη. Η συνθήκη >0 περιέχεται στο κελί A13. Ο τύπος στο κελί E13 είναι ο παρακάτω:

=SUMIF(E2:E11;A13)

Τώρα προβάλετε την απόσβεση για μια περίοδο 10 ετών ή με υπολειμματική αξία 1 νομισματικής μονάδας ή εισαγάγετε ένα διαφορετικό αρχικό κόστος κτλ.

## DURATION

Υπολογίζει τη διάρκεια ενός τίτλου σταθερού επιτοκίου, σε έτη.

Οι συναρτήσεις των οποίων τα ονόματα τελειώνουν με _ADD ή _EXCEL2003 επιστρέφουν τα ίδια αποτελέσματα όπως οι αντίστοιχες συναρτήσεις του Microsoft Excel 2003 χωρίς την κατάληξη . Χρησιμοποιήστε τις συναρτήσεις χωρίς κατάληξη για να πάρετε αποτελέσματα βασισμένα στα διεθνή πρότυπα.

#### Σύνταξη

DURATION("Settlement"; "Maturity"; Coupon; Yield; Frequency; Basis)

Διακανονισμός είναι η ημερομηνία αγοράς του τίτλου.

Ωρίμανση είναι η ημερομηνία κατά την οποία λήγει ο τίτλος.

Τοκομερίδιο είναι το ετήσιο τοκομερίδιο επιτοκίου (ονομαστικό επιτόκιο)

Απόδοση είναι η ετήσια απόδοση του τίτλου.

Συχνότητα είναι ο αριθμός των πληρωμών τόκου ετησίως (1, 2 ή 4).

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

#### Παράδειγμα

Ένας τίτλος αγοράζεται στις 1/1/2001. Η ημερομηνία λήξης είναι 1/1/2006. Το ονομαστικό επιτόκιο είναι 8%. Η απόδοση είναι 9,0%. Ο τόκος καταβάλλεται ανά εξάμηνο (η συχνότητα περιόδων είναι 2). Χρησιμοποιώντας τη μέθοδο υπολογισμού ημερήσιου τόκου (βάση 3), ποια είναι η τροποποιημένη περίοδος;

=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3)

## IRR

Υπολογίζει το εσωτερικό επιτόκιο απόδοσης (βαθμός απόδοσης) μιας επένδυσης. Οι τιμές αναπαριστούν τις χρηματικές ροές σε τακτά διαστήματα, τουλάχιστον μία πρέπει να είναι αρνητική (πληρωμές) και τουλάχιστον μία να είναι θετική (εισόδημα).

Αν οι πληρωμές λαμβάνουν χώρα σε ακανόνιστα διαστήματα, χρησιμοποιήστε τη συνάρτηση .

#### Σύνταξη

IRR(Τιμές; Εκτίμηση)

Τιμές αντιπροσωπεύει έναν πίνακα που περιέχει τις τιμές.

Εκτίμηση (προαιρετικό) είναι η εκτιμώμενη τιμή. Νια επαναληπτική μέθοδος χρησιμοποιείται για τον υπολογισμό του εσωτερικού επιτοκίου απόδοσης. Εάν μπορείτε να παράσχετε μόνο μερικές τιμές, θα μπορούσατε να παράσχετε μια αρχική εκτίμηση για ενεργοποίηση της επανάληψης.

#### Παράδειγμα

Με την υπόθεση ότι τα περιεχόμενα κελιών είναι A1=-10000, A2=3500, A3=7600 και A4=1000, ο τύπος =IRR(A1:A4) δίνει ένα αποτέλεσμα του 11,33%.

Λόγω της χρησιμοποιούμενης επαναληπτικής μεθόδου. είναι δυνατό το IRR να αποτύχει και να επιστρέψει Σφάλμα 523, με "Σφάλμα: Ο υπολογισμός δεν συγκλίνει" στη γραμμή κατάστασης. Σε αυτήν την περίπτωση, δοκιμάστε μια άλλη τιμή για την εκτίμηση.

## AMORLINC

Υπολογίζει το ποσό απόσβεσης για μια περίοδο διακανονισμού ως γραμμικό χρεολύσιο. Εάν το περιουσιακό στοιχείο (πάγιο) αγοράστηκε κατά τη διάρκεια της περιόδου διακανονισμού, εξετάζεται το αναλογικό ποσό της απόσβεσης.

#### Σύνταξη

AMORLINC(Κόστος;ΗμερομηνίαΑγοράς;ΠρώτηΠερίοδος;ΥπολειμματικήΑξία;Περίοδος;Συντελεστής;Βάση)

Κόστος σημαίνει τα κόστη κτήσης.

ΗμερομηνίαΑγοράς είναι η ημερομηνία απόκτησης.

ΠρώτηΠερίοδος είναι η τελική ημερομηνία της πρώτης περιόδου πληρωμής.

ΥπολειμματικήΑξία είναι η τιμή υπολειμματικής αξίας του περουσιακού κεφαλαίου στο τέλος της ζωής απόσβεσης.

Περίοδος είναι η θεωρούμενη περίοδος πληρωμής.

Επιτόκιο είναι το επιτόκιο της απόσβεσης.

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

## AMORDEGRC

Υπολογίζει το ποσό απόσβεσης για μια περίοδο διακανονισμού ως φθίνον χρεολύσιο. Σε αντίθεση με τη συνάρτηση AMORLINC, εδώ χρησιμοποιείται ένας συντελεστής απόσβεσης ο οποίος είναι ανεξάρτητος από τη διάρκεια ζωής απόσβεσης.

#### Σύνταξη

AMORDEGRC (Κόστος;ΗμερομηνίαΑγοράς;ΠρώτηΠερίοδος;ΥπολειμματικήΑξία;Περίοδος;Επιτόκιο;Βάση)

Κόστος είναι τα κόστη κτήσης.

ΗμερομηνίαΑγοράς είναι η ημερομηνία απόκτησης.

ΠρώτηΠερίοδος είναι η τελική ημερομηνία της πρώτης περιόδου πληρωμής.

ΥπολειμματικήΑξία είναι η τιμή υπολειμματικής αξίας του περουσιακού κεφαλαίου στο τέλος της ζωής απόσβεσης.

Περίοδος είναι η θεωρούμενη περίοδος πληρωμής.

Επιτόκιο είναι το επιτόκιο της απόσβεσης.

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

## RECEIVED

Υπολογίζει το ποσό που έχει εισπραχθεί, το οποίο καταβάλλεται για έναν τίτλο σταθερού επιτοκίου, σε μια δεδομένη χρονική στιγμή.

#### Σύνταξη

RECEIVED("Διακανονισμός"; "Ωρίμανση"; Επένδυση; Προεξόφληση; Βάση)

Διακανονσιμός είναι η ημερομηνία αγοράς του τίτλου.

Ωρίμανση είναι η ημερομηνία κατά την οποία λήγει ο τίτλος.

Επένδυση είναι το ποσό αγοράς.

Η Προεξόφληση είναι το ποσοστό προεξόφλησης κατά την αγορά του τίτλου.

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

#### Παράδειγμα

Ημερομηνία διακανονισμού: 15 Φεβρουαρίου 1999, ημερομηνία λήξης: 15 Μαΐου 1999, ποσό επένδυσης: 1000 νομισματικές μονάδες, προεξόφληση: 5.75 τοις εκατό, βάση: Ημερήσιο υπόλοιπο/360 = 2.

Το ποσό που εισπράχθηκε κατά την ημερομηνία λήξης υπολογίζεται ως εξής:

Η συνάρτηση =RECEIVED("1999-02-15";"1999-05-15";1000;0,0575;2) επιστρέφει ως αποτέλεσμα 1014,420266.

## EFFECT_ADD

Υπολογίζει το πραγματικό ετήσιο επιτόκιο με βάση το ονομαστικό επιτόκιο και τον αριθμό των καταβολών τόκου ετησίως.

Οι συναρτήσεις των οποίων τα ονόματα τελειώνουν με _ADD ή _EXCEL2003 επιστρέφουν τα ίδια αποτελέσματα όπως οι αντίστοιχες συναρτήσεις του Microsoft Excel 2003 χωρίς την κατάληξη . Χρησιμοποιήστε τις συναρτήσεις χωρίς κατάληξη για να πάρετε αποτελέσματα βασισμένα στα διεθνή πρότυπα.

#### Σύνταξη

EFFECTIVE_ADD(ΟνομαστικόΕπιτόκιο; ΑριθμόςΠεριόδωνΈτους)

ΟνομαστικόΕπιτόκιο είναι το ετήσιο ονομαστικό επιτόκιο.

ΑριθμόςΠεριόδωνΈτους είναι ο αριθμός των πληρωμών τόκου ετησίως.

#### Παράδειγμα

Ποιο είναι το πραγματικό επιτόκιο για ένα ονομαστικό επιτόκιο 5,25% και τριμηνιαίες πληρωμές.

Το =EFFECT_ADD(0,0525;4) επιστρέφει 0,053543 ή 5,3534%.

## DISC

Υπολογίζει το προεξοφλητικό επιτόκιο ενός τίτλου ως ποσοστό.

#### Σύνταξη

DISC("Διακανονισμός"; "Ωρίμανση"; Τιμή; Εξαγορά; Βάση)

Διακανονσιμός είναι η ημερομηνία αγοράς του τίτλου.

Ωρίμανση είναι η ημερομηνία κατά την οποία λήγει ο τίτλος.

Τιμή είναι η τιμή του τίτλου ανά 100 νομισματικές μονάδες της ονομαστικής τιμής.

Εξαγορά είναι η τιμή εξαγοράς του τίτλου ανά 100 νομισματικές μονάδες της ονομαστικής αξίας.

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

#### Παράδειγμα

Γίνεται αγορά ενός τίτλου στις 25.1.2001. Η ημερομηνία λήξης είναι στις 15.11.2001. Η τιμή (τιμή αγοράς) είναι 97, η τιμή εξαγοράς είναι 100. Χρησιμοποιώντας τον υπολογισμός ημερήσιου υπολοίπου (βάση 3), πόσο υψηλός είναι ο διακανονισμός (προεξόφληση);

Η συνάρτηση =DISC("2001-01-25";"2001-11-15";97;100;3) επιστρέφει ως αποτέλεσμα 0,0372 ή 3,72 τοις εκατό.

## ACCRINTM

Υπολογίζει το συσσωρευμένο τόκο ενός τίτλου, στην περίπτωση καταβολής εφάπαξ, κατά την ημερομηνία διακανονισμού.

#### Σύνταξη

ACCRINTM (Έκδοση; Διακανονισμός; Επιτόκιο; ΟνομαστικήAξία; Βάση)

Έκδοση (απαιτείται) είναι η ημερομηνία έκδοσης του τίτλου.

Διακανονισμός (απαιτείται) είναι η ημερομηνία στην οποία οι μέχρι τότε σωρευμένοι τόκοι πρέπει να υπολογιστούν.

Επιτόκιο (απαιτείται) είναι το ετήσιο ονομαστικό επιτόκιο (επιτόκιο τοκομεριδίου).

ΟνομαστικήΑξία (προαιρετικό) είναι η τιμή της ονομαστικής αξίας του τίτλου.

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

#### Παράδειγμα

Ένας τίτλος εκδόθηκε στις 1.4.2001. Η ημερομηνία λήξης έχει οριστεί για τις 15.6.2001. Το ονομαστικό επιτόκιο είναι 0,1 ή 10%, η ονομαστική αξία είναι 1000 νομισματικές μονάδες. Η βάση του ημερήσιου/ετήσιου υπολογισμού είναι το ημερήσιο υπόλοιπο (3). Ποιος είναι ο τόκος που έχει συσσωρευτεί;

Η συνάρτηση =ACCRINTM("1.4.2001";"15.6.2001";0,1;1000;3) επιστρέφει ως αποτέλεσμα 20,54795.

## ACCRINT

Υπολογίζει το συσσωρευμένο τόκο ενός τίτλου, στην περίπτωση καταβολής με περιοδικές πληρωμές.

#### Σύνταξη

ACCRINT (Έκδοση; ΠρώτοςTόκος; Διακανονισμός; Επιτόκιο; ΟνομαστικήAξία; Συχνότητα; Βάση)

Έκδοση (απαιτείται) είναι η ημερομηνία έκδοσης της ασφάλειας.

ΠρώτοςΤόκος (απαιτείται) είναι η ημερομηνία πρώτου τόκου της ασφάλειας.

Διακανονισμός (απαιτείται) είναι η ημερομηνία μέχρι την οποία οι μέχρι τότε σωρευμένοι τόκοι πρέπει να υπολογιστούν.

Επιτόκιο (απαιτείται) είναι το ετήσιο ονομαστικό επιτόκιο (επιτόκιο τοκομεριδίων)

ΟνομαστικήΑξία (προαιρετικό) είναι η τιμή της ονομαστικής αξίας του τίτλου.

Συχνότητα (απαιτείται) είναι ο αριθμός των πληρωμών τόκου ετησίως (1, 2 ή 4).

Η Βάση (προαιρετική) επιλέγεται από έναν κατάλογο επιλογών και υποδηλώνει πώς πρόκειται να υπολογιστεί το έτος.

Βάση | Υπολογισμός
0 or missing | Μέθοδος ΗΠΑ (NASD), 12 μήνες των 30 ημερών ο καθένας
1 | Ακριβής αριθμός ημερών σε μήνες, ακριβής αριθμός ημερών σε έτος
2 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 360 ημέρες
3 | Ακριβής αριθμός ημερών σε μήνα, ένα έτος αποτελείται από 365 ημέρες
4 | Ευρωπαϊκή μέθοδος, 12 μήνες των 30 ημερών ο καθένας

#### Παράδειγμα

Ένας τίτλος εκδόθηκε στις 28.2.2001. Η ημερομηνία πρώτου τοκισμού έχει οριστεί για τις 31.8.2001. Η ημερομηνία διακανονισμού είναι στις 1.5.2001. Το ονομαστικό επιτόκιο είναι 0,1 ή 10%, η ονομαστική αξία είναι 1000 νομισματικές μονάδες. Ο τόκος καταβάλλεται σε εξαμηνιαία βάση (η συχνότητα είναι 2). Η βάση είναι η μέθοδος ΗΠΑ (0). Ποιος είναι ο τόκος που έχει συσσωρευτεί;

Η συνάρτηση =ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0,1;1000;2;0) επιστρέφει ως αποτέλεσμα 16,94444.

Μετάβαση στις Οικονομικές συναρτήσεις - Μέρος δεύτερο

Μετάβαση στις Οικονομικές συναρτήσεις - Μέρος τρίτο

Συναρτήσεις ανά κατηγορία