# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname=aas-sign
pkgbase="mingw-w64-${_realname}"
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=1.1.0
pkgrel=1
pkgdesc="Azure Artifact Signing utility (mingw-w64)"
arch=('any')
mingw_arch=('ucrt64' 'clang64' 'clangarm64')
url='https://github.com/skeeto/aas-sign'
license=('spdx:Unlicense')
depends=("${MINGW_PACKAGE_PREFIX}-cc-libs")
makedepends=("${MINGW_PACKAGE_PREFIX}-cc"
             "${MINGW_PACKAGE_PREFIX}-cmake"
             "${MINGW_PACKAGE_PREFIX}-ninja"
             "${MINGW_PACKAGE_PREFIX}-nlohmann-json")
source=("${_realname}-${pkgver}.tar.gz::https://github.com/skeeto/${_realname}/archive/refs/tags/v${pkgver}.tar.gz"
        "0001-add-install-rules.patch")
sha256sums=('33797c3866c0f61ddde1ec60951b43c77da6edd1376c0969fcb8f18a11bc2a87'
            '52f934fbb3ff15f407e9193b4de8403926d261dcad68ef79ed1f2c49d6ba74ce')

prepare() {
  cd "${_realname}-${pkgver}"

  patch -Np1 -i "${srcdir}/0001-add-install-rules.patch"
}

build() {
  declare -a extra_config
  if check_option "debug" "n"; then
    extra_config+=("-DCMAKE_BUILD_TYPE=Release")
  else
    extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
  fi

  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    cmake \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX="${MINGW_PREFIX}" \
      "${extra_config[@]}" \
      -DFETCHCONTENT_FULLY_DISCONNECTED=1 \
      -DDEPS=LOCAL \
      -S "${_realname}-${pkgver}" \
      -B "build-${MSYSTEM}"

  cmake --build "build-${MSYSTEM}"
}

package() {
  DESTDIR="${pkgdir}" cmake --install "build-${MSYSTEM}"

  install -Dm644 "${_realname}-${pkgver}/UNLICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/UNLICENSE"
}
