# Contributor: Dirk Stolle

_realname=File-ShareDir-Install
pkgname=perl-${_realname}
pkgver=0.14
pkgrel=1
pkgdesc="File::ShareDir::Install - Install read-only data files from a distribution"
arch=('i686' 'x86_64')
license=('spdx:GPL-1.0-only' 'spdx:Artistic-1.0-Perl')
url='https://metacpan.org/dist/File-ShareDir-Install'
msys2_repository_url='https://github.com/Perl-Toolchain-Gang/File-ShareDir-Install'
msys2_changelog_url='https://github.com/Perl-Toolchain-Gang/File-ShareDir-Install/blob/master/Changes'
msys2_references=(
  "purl: pkg:cpan/ETHER/File-ShareDir-Install"
)
groups=('perl-modules')
depends=('perl')
makedepends=('perl-devel' 'make')
checkdepends=('perl-Test-Pod')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/E/ET/ETHER/${_realname}-${pkgver}.tar.gz")
sha256sums=('8f9533b198f2d4a9a5288cbc7d224f7679ad05a7a8573745599789428bc5aea0')

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make test
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"
  make install DESTDIR="${pkgdir}"
}
